<xsl:template mode="mdTxt" match="ce:Description">
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template mode="mdTxt" match="ce:TaxAmount">
  <xsl:call-template name="textLabelByTagName"/>
  <xsl:call-template name="getLabelSeprator"/>
  <xsl:value-of select="."/>
</xsl:template>

<xsl:template mode="mdTxt" match="ce:PaymentTerms">
  <xsl:if test="@term">
    <xsl:value-of select="@term"/>
    <xsl:text> </xsl:text>
    <xsl:call-template name="getLabel">
      <xsl:with-param name="aVal">days</xsl:with-param>
    </xsl:call-template>
    <xsl:text> </xsl:text>
  </xsl:if>
  <xsl:if test="@netOrEOM">
    <xsl:call-template name="getLabel">
      <xsl:with-param name="aList">net_or_eom_list_type</xsl:with-param>
      <xsl:with-param name="aVal" select="@netOrEOM"/>
    </xsl:call-template>
  </xsl:if>
  <xsl:if test="@monthDay">
    <xsl:text>, </xsl:text>
    <xsl:call-template name="getLabel">
      <xsl:with-param name="aVal">monthDay1</xsl:with-param>
    </xsl:call-template>
    <xsl:text> </xsl:text>
    <xsl:value-of select="@monthDay"/>
    <xsl:text> </xsl:text>
    <xsl:call-template name="getLabel">
      <xsl:with-param name="aVal">monthDay2</xsl:with-param>
    </xsl:call-template>
  </xsl:if>
  <xsl:if test="@dateRef">
    <xsl:text> (</xsl:text>
    <xsl:call-template name="getLabel">
      <xsl:with-param name="aVal">dateRef</xsl:with-param>
    </xsl:call-template>
    <xsl:call-template name="getLabelSeprator"/>
    <xsl:call-template name="getLabel">
      <xsl:with-param name="aList">payment_date_ref_list_type</xsl:with-param>
      <xsl:with-param name="aVal" select="@dateRef"/>
    </xsl:call-template>
    <xsl:text>)</xsl:text>
  </xsl:if>
</xsl:template>

<xsl:template name="tplEx">
  <!-- cmt: Complete with additional extension -->
  <!-- $aSep : optional separtor -->
  <xsl:choose>
    <xsl:when test="@currency">
      <xsl:text> </xsl:text>
      <xsl:value-of select="@currency"/>
    </xsl:when>
    <xsl:when test="@unit">
      <xsl:text> </xsl:text>
      <xsl:if test="local-name(.) != 'Width'">
        <xsl:value-of select="@unit"/>
      </xsl:if>
    </xsl:when>
    <xsl:otherwise>
      <xsl:if test="name()='Money'">
        <xsl:if test="//ce:InvoiceDetailRequestHeader/@currency">
          <xsl:text> </xsl:text>
          <xsl:value-of select="//ce:InvoiceDetailRequestHeader/@currency"/>
        </xsl:if>
        <xsl:if test="//ce:OrderRequestHeader/@currency">
          <xsl:text> </xsl:text>
          <xsl:value-of select="//ce:OrderRequestHeader/@currency"/>
        </xsl:if>
      </xsl:if>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="ce:PricePerUnit">
  <xsl:apply-templates/>
  <xsl:if test="@unit">
    <xsl:text> /</xsl:text>
    <xsl:value-of select="@unit"/>
  </xsl:if>
</xsl:template>

<xsl:template match="ce:Percentage">
  <xsl:value-of select="concat(@percent, '%')"/>
</xsl:template>

<xsl:template match="ce:TelephoneNumber">
  <xsl:value-of select="concat('+',ce:CountryCode, ' (0)', ce:AreaOrCityCode, ' ', ce:Number)"/>
</xsl:template>

<xsl:template match="ce:PackingLevelCode">
  <xsl:text> - </xsl:text>
  <xsl:variable name="iKey" select="concat(local-name(), .)"/>
  <xsl:call-template name="getLabel">
    <xsl:with-param name="aVal" select="$iKey"/>
  </xsl:call-template>
</xsl:template>

<xsl:template match="ce:CarrierIdentifier">
  <xsl:if test="@domain">
    <xsl:call-template name="getSpanLabel">
      <xsl:with-param name="aVal" select="@domain"/>
    </xsl:call-template>
  </xsl:if>
  <xsl:apply-templates/>
</xsl:template>